seccomp-sandbox/flake.nix

{
  inputs = {
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixpkgs.url = "nixpkgs/nixos-unstable";
  };
  outputs = { nixpkgs, fenix, ... }:
    let
      systems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
      foreachSystem = nixpkgs.lib.genAttrs systems;

      buildTools = pkgs: with pkgs; [
        pkg-config # hooks pc files into environment variable for futher usage
      ];
      developmentTools = pkgs: with pkgs; [
        cargo-expand
      ];
      libraries = pkgs: with pkgs; [
        libseccomp
      ];

      buildRustPlatform = pkgs: with fenix.packages."${pkgs.stdenv.system}"; let toolchain = combine [ complete.toolchain targets."x86_64-unknown-linux-musl".latest.rust-std ]; in pkgs.makeRustPlatform {
        cargo = toolchain;
        rustc = toolchain;
      };

      buildWithPackages = pkgs: pkgsStatic: (buildRustPlatform pkgsStatic).buildRustPackage rec {
        pname = "x2t-sandbox";
        version = "1.0.0";

        nativeBuildInputs = buildTools pkgs;
        buildInputs = libraries pkgsStatic;

        src = ./.;

        cargoLock = {
          lockFile = ./Cargo.lock;
        };

        meta = with nixpkgs.lib; {
          description = "seccomp sandbox with rules defined at build stage";
          homepage = "https://gitea.jianguoyun.net.cn/guochao/x2t-sandbox";
          license = licenses.unlicense;
          maintainers = [ ];
        };
      };
    in
    rec {
      packages = foreachSystem (system:
        let
          pkgs = import nixpkgs { inherit system; };
        in
        rec {
          x2t-sandbox-static = buildWithPackages pkgs pkgs.pkgsStatic;
          x2t-sandbox = buildWithPackages pkgs pkgs;

          default = x2t-sandbox-static;
        });
      devShells = foreachSystem
        (system:
          let
            pkgs = import nixpkgs { inherit system; };
          in
          with pkgs; rec {
            default = packages."${system}".default.overrideAttrs (prevAttrs: {
              nativeBuildInputs = prevAttrs.nativeBuildInputs ++ (with fenix.packages."${system}".combine; with fenix.packages."${system}"; with pkgs; [
                complete.rust-analyzer
                complete.rust-src
              ]) ++ (developmentTools pkgs);
            });
          });
    };
}